Программируем Arduino. Профессиональная работа со скетчами

Библиотека SPI входит в состав Arduino IDE, поэтому вам не придется ничего устанавливать, чтобы воспользоваться ею. Но она поддерживает только сценарии, когда плата Arduino действует в роли ведущего устройства. Кроме того, библиотека поддерживает передачу данных только целыми байтами. Для большинства периферийных устройств этого вполне достаточно, однако некоторые устройства предполагают обмен 12-битными сообщениями, что несколько осложняет обмен из-за необходимости манипуляций с битами, как будет показано в примере в следующем разделе.

Прежде всего, как обычно, необходимо подключить библиотеку SPI:

#include

Затем инициализировать ее командой SPI.begin в функции запуска передачи:

void setup()

{

  SPI.begin();

  pinMode(chipSelectPin, OUTPUT);

  digitalWrite(chipSelectPin, HIGH);

}

Для моделей платы Arduino, кроме Due, нужно также настроить цифровые выходы для всех линий выбора ведомых устройств. Роль таких выходов могут играть любые контакты на плате Arduino. После настройки их на работу в режиме выходов требуется сразу же установить на них уровень напряжения HIGH из-за инвертированной логики выбора ведомого, согласно которой напряжение LOW означает, что данное устройство выбрано.

Для модели Due имеется расширенная версия библиотеки SPI, поэтому достаточно определить контакт для выбора ведомого — и библиотека автоматически будет устанавливать на нем уровень LOW перед передачей и возвращать уровень HIGH по ее окончании. Для этого нужно передать коман­де SPI.begin аргумент с номером контакта. Недостаток такого подхода заключается в нарушении совместимости с другими моделями Arduino. В примерах, приводимых далее, все ведомые устройства выбираются вручную, и потому эти примеры будут работать на всех платах Arduino.

Для настройки соединения через интерфейс SPI имеется множество вспомогательных функций. Однако параметры по умолчанию вполне подходят для большинства случаев, поэтому изменять их нужно, только если документация с описанием ведомого устройства требует их изменения. Эти функции перечислены в табл. 9.3.

Таблица 9.3. Вспомогательные функции

Функция

Описание

SPI.setClockDivider(SPI_CLOCK_DIV64)

Выполняет деление тактовой частоты (по умолчанию равна 4 МГц) на 2, 4, 8, 16, 32, 64 или 128

SPI.setBitOrder(LSBFIRST)

Устанавливает порядок передачи битов LSBFIRST (от младшего к старшему) или MSBFIRST (от старшего к младшему). По умолчанию используется порядок MSBFIRST

SPI.setDataMode(SPI_MODE0)

Возможные значения аргументов этой функции от SPI_MODE0 до SPI_MODE3. Определяют полярность и фазу тактового сигнала. Обычно нет необходимости изменять эту настройку, если только документация не требует установить какой-то определенный режим работы для организации обмена с ведомым устройством

Объединенные передача и прием происходят в функции transfer. Эта функция посылает байт данных и возвращает байт данных, принятый в процессе передачи:

byte sendByte = 0x23;

byte receiveByte = SPI.transfer(sendByte);

Поскольку диалог с периферией обычно имеет форму запроса со стороны ведущего и ответа со стороны ведомого, часто последовательно выполняются две передачи данных: одна — запрос, другая (возможно, во время передачи нулей) — ответ периферийного устройства. Вы увидите, как это происходит, в следующем примере.

Пример SPI

Этот пример демонстрирует взаимодействие платы Arduino с интегральной микросхемой восьмиканального АЦП MCP3008, добавляющего еще восемь 10-битных аналоговых входов. Эта микросхема стоит очень недорого и легко подключается к плате. На рис. 9.6 изображена схема подключения микросхемы к плате Arduino с использованием макетной платы и нескольких проводов. Переменное сопротивление служит для изменения уровня напряжения на аналоговом входе 0 между 0 и 5 В.

Рис. 9.6. Схема соединения компонентов для примера SPI

Ниже приводится скетч для этого примера:

// sketch_09_01_SPI_ADC

#include

const int chipSelectPin = 10;

void setup()

{

  Serial.begin(9600);

  SPI.begin();

  pinMode(chipSelectPin, OUTPUT);

  digitalWrite(chipSelectPin, HIGH);

}

void loop()

{

  int reading = readADC(0);

  Serial.println(reading);

  delay(1000);

}

int readADC(byte channel)

{

  unsigned int configWord = 0b11000 | channel;

  byte configByteA = (configWord >> 1);

  byte configByteB = ((configWord & 1) << 7);

  digitalWrite(chipSelectPin, LOW);

  SPI.transfer(configByteA);

  byte readingH = SPI.transfer(configByteB);

  byte readingL = SPI.transfer(0);

  digitalWrite(chipSelectPin, HIGH);

//  printByte(readingH);

//  printByte(readingL);

  int reading = ((readingH & 0b00011111) << 5)

              + ((readingL & 0b11111000) >> 3);

  return reading;

}

void printByte(byte b)

{

  for (int i = 7; i >= 0; i--)

  {

     Serial.print(bitRead(b, i));

  }

  Serial.print(" ");

}