PIC-микроконтроллеры. Все, что вам необходимо знать

На Рис. 6.11, а показано вычисление значения √65 описанным способом. Блок-схема этого алгоритма показана на Рис. 6.11, б, а код подпрограммы приведен в Программе 6.12. Максимальное значение счетчика цикла равно h’FF’, поскольку √(65535)~=255. Поэтому под данную локальную переменную резервируется всего один регистр h’35’. Аналогично, максимально возможное значение магического числа I равно 511 (h’1FF’), поэтому под эту локальную переменную резервируется уже два регистра h’36’:h’37’. Отсюда следует, что на этапе За выполняется двухбайтное вычитание. При возникновении заема из младшего байта, к копии старшего байта I (I_Н) перед вычитанием добавляется 1. Поскольку I_Н никогда не будет больше h’01’, указанная операция никогда не вызовет переполнения. Если заем генерируется при вычитании из этого старшего байта, ЭТО означает, что результат стал меньше нуля и цикл завершается. В противном случае COUNT инкрементируется, а I умножается на 2. На самом деле значение счетчика цикла всегда равно I/2 — 1, так что переменная COUNT не нужна. Вместо этого при возврате из подпрограммы можно просто сдвинуть 16-битное значение / на один разряд вправо. При этом произойдет деление на 2, а вычитание единицы производится посредством отбрасывания бита, выдвинутого в флаг переноса (I всегда нечетное, поэтому младший бит этого числа всегда равен 1). Попробуйте реализовать этот альтернативный алгоритм.

Рис. 6.11.Нахождение корня квадратного из целого числа

Программа 6.12. Подпрограмма вычисления квадратного корня

; Глобальные объявления

STATUS equ 3; Регистр STATUS

equ 0; Флаг переноса — бит 0

NUM_H equ h’26’; Исходное значение, старший байт

NUM_L equ h’27’; Исходное значение, младший байт

; ****************

; * ФУНКЦИЯ: Вычисляет корень квадратный из 16-битного целого *

; * ПРИМЕР: Число = h’FFFF’ (65,535), Корень = h’FF’ (d’255’)*

; * ВХОД: Число в регистрах h’26’:h’27’ *

; * ВЫХОД: Корень в W. Регистры h’26’:h’27’ и h’35’:h’36’:h’37’ изменяются *

; *****************

; Локальные объявления

COUNT equ h’35’; Счетчик цикла

I_Н equ h’36’; Магическое число, старший байт

I_L equ h’37’; Магическое число, младший байт

; Задача 1: Обнулить счетчик цикла

SQR_ROOT clrf COUNT

; Задача 2: Инициализация магического числа единицей

                clrf I_L

                clrf I_H

                incf I_L,f

; Задача 3: ВЫПОЛНИТЬ

; Задача 3а: Number — I

SQR_LOOP movf I_L,w; Берем младший байт магического числа

                 subwf NUM_L,f; Вычитаем из младшего байта исходного числа

                 movf I_H,W; Берем старой байт магического числа

                 btfss STATUS,С; ЕСЛИ не было заема (С==1), ТО пропускаем

                    addlw 1; Учитываем заем

                 subwf NUM_H,f; Вычитаем старшие байты

; Задача 3б: ЕСЛИ потеря значимости, ТО выйти

                 btfss STATUS,С; ЕСЛИ нет заема (С==1), ТО продолжаем

                    goto SQR_END; ИНАЧЕ вычисление завершено

; Задача Зв: ИНАЧЕ инкрементировать счетчик цикла

                  incf COUNT,f

; Задача 3г: Увеличить магическое число на 2

                  movf I_L,w

                  addlw 2

                  btfsc STATUS,С; Если нет переноса, ТО пропускаем

                    incf I_H,f; ИНАЧЕ корректируем старший байт

                      movwf I_L

                      goto SQR_LOOP

; Задача 4: Вернуть счетчик цикла в качестве значения корня

SQR_END movf COUNT,w; Копируем результат в W

                      return

Пример 6.6

Напишите программу умножения содержимого регистра h’46’ на десять (х2 + х8). Для хранения данных и передачи параметров воспользуйтесь программным стеком.

Решение

Объявления глобальных переменных для подпрограммы, код которой приведен в Программе 6.13, и вызывающей процедуры следующие: